Texture Coordinates Solve Transform

This is a quick workup of solving for texture coordinates given three pairings. In the next equation the six degree of freedom transformation mapping from a 3D coordinate on a survace and a 2D coordinate in a texture map is expressed using six free variables indicated 'a' through 'f'.

Ross Beveridge, November 21, 2019

var('a', 'b', 'c', 'd', 'e', 'f')
var('x', 'y', 'z')
var('u','v')
TM = Matrix(SR, 2,3, ((a,b,c),(d,e,f)))
UV = Matrix(SR, 2,1, ((u),(v)))
PT = Matrix(SR, 3,1, ((x),(y),(z)))
pretty_print(UV, LatexExpr(" = "), TM, PT)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{r} u \\ v \end{array}\right) = \left(\begin{array}{rrr} a & b & c \\ d & e & f \end{array}\right) \left(\begin{array}{r} x \\ y \\ z \end{array}\right)$$

Now recognize that when given a point in 3D and a point in 2D there are actually two resulting constraint equations that 'a' through 'f' must satisfy. Two constraints and sixe unknowns is not yet enough to fully solve for a transformation, but that will come next.

TMPT = TM * PT
pretty_print(UV, LatexExpr(" = "), TMPT)
eq1 = (UV[0,0] == TMPT[0,0])
eq2 = (UV[1,0] == TMPT[1,0])
pretty_print("Constraint One: \b", eq1)
pretty_print("Constraint Two: \b", eq2)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{r} u \\ v \end{array}\right) = \left(\begin{array}{r} a x + b y + c z \\ d x + e y + f z \end{array}\right)$$

$$\newcommand{\Bold}[1]{\mathbf{#1}}\verb|Constraint|\phantom{\verb!x!}\verb|One:|\phantom{\verb!x!}\verb|| u = a x + b y + c z$$

$$\newcommand{\Bold}[1]{\mathbf{#1}}\verb|Constraint|\phantom{\verb!x!}\verb|Two:|\phantom{\verb!x!}\verb|| v = d x + e y + f z$$

Now we need to setup the problem of solving for the six free variables based upon known correspondence between three points as expressed before and after applicaiton of the mapping. In other words, three instances of paired points in 3D then 2D. When we do this, we get the following two Y = M X style linear equations. Each is solved by inverting the matrix M. And notice, it is the same matrix in both cases.

var('u1', 'u2', 'u3')
var('v1', 'v2', 'v3')
var('x1', 'y1', 'z1')
var('x2', 'y2', 'z2')
var('x3', 'y3', 'z3')
YU = Matrix(SR, 3,1, ((u1),(u2),(u3)))
YV = Matrix(SR, 3,1, ((v1),(v2),(v3)))
MM = Matrix(SR, 3,3, ((x1, y1, z1),(x2, y2, z2),(x3, y3, z3)))
XU = Matrix(SR, 3,1, ((a),(b),(c)))
XV = Matrix(SR, 3,1, ((d),(e),(f)))
pretty_print(YU, LatexExpr(" = "), MM, XU)
pretty_print(YV, LatexExpr(" = "), MM, XV)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{r} u_{1} \\ u_{2} \\ u_{3} \end{array}\right) = \left(\begin{array}{rrr} x_{1} & y_{1} & z_{1} \\ x_{2} & y_{2} & z_{2} \\ x_{3} & y_{3} & z_{3} \end{array}\right) \left(\begin{array}{r} a \\ b \\ c \end{array}\right)$$

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{r} v_{1} \\ v_{2} \\ v_{3} \end{array}\right) = \left(\begin{array}{rrr} x_{1} & y_{1} & z_{1} \\ x_{2} & y_{2} & z_{2} \\ x_{3} & y_{3} & z_{3} \end{array}\right) \left(\begin{array}{r} d \\ e \\ f \end{array}\right)$$

To see how this works in practice, let us setup three points matching three points. Note that the compact form of the constraints is being shown in a single linear algebraid equation.

PTS2Dt = Matrix(SR, 3,2, ((0,0),(0,1),(1,0)))
PTS2D  = PTS2Dt.transpose()
PTS3Dt = Matrix(SR, 3,3, ((1,2,3),(4,4,4),(9,8,8)))
PTS3D  = PTS3Dt.transpose()
pretty_print(PTS2D, LatexExpr(" = "), TM, PTS3D)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{rrr} 0 & 0 & 1 \\ 0 & 1 & 0 \end{array}\right) = \left(\begin{array}{rrr} a & b & c \\ d & e & f \end{array}\right) \left(\begin{array}{rrr} 1 & 4 & 9 \\ 2 & 4 & 8 \\ 3 & 4 & 8 \end{array}\right)$$

PTS3D.is_invertible()

True

M2 = PTS3D.inverse()
pretty_print(TM, LatexExpr(" = "), PTS2D, M2)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{rrr} a & b & c \\ d & e & f \end{array}\right) = \left(\begin{array}{rrr} 0 & 0 & 1 \\ 0 & 1 & 0 \end{array}\right) \left(\begin{array}{rrr} 0 & -1 & 1 \\ -2 & \frac{19}{4} & -\frac{5}{2} \\ 1 & -2 & 1 \end{array}\right)$$

TMnum = PTS2D * M2
pretty_print(TM, LatexExpr(" = "), TMnum)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{rrr} a & b & c \\ d & e & f \end{array}\right) = \left(\begin{array}{rrr} 1 & -2 & 1 \\ -2 & \frac{19}{4} & -\frac{5}{2} \end{array}\right)$$

Confirm that multiplying the transformation matrix with the 3D points yeilds the specified original 2D points

pretty_print(PTS2D, LatexExpr(" = "), TMnum * PTS3D)

$$\newcommand{\Bold}[1]{\mathbf{#1}}\left(\begin{array}{rrr} 0 & 0 & 1 \\ 0 & 1 & 0 \end{array}\right) = \left(\begin{array}{rrr} 0 & 0 & 1 \\ 0 & 1 & 0 \end{array}\right)$$